sailfork / t3code-github / apps/ mobile/ modules/ t3-terminal/ android/ build.gradle

apply plugin: 'com.android.library'
apply plugin: 'org.jetbrains.kotlin.android'

group = 'com.t3tools.terminal'
version = '0.0.0'

android {
  namespace 'expo.modules.t3terminal'
  ndkVersion rootProject.ext.ndkVersion
  compileSdk rootProject.ext.compileSdkVersion

  testOptions {
    unitTests.includeAndroidResources = true
  }

  defaultConfig {
    minSdkVersion rootProject.ext.minSdkVersion
    targetSdkVersion rootProject.ext.targetSdkVersion

    def requestedArchitectures = project.findProperty('reactNativeArchitectures')
    if (requestedArchitectures) {
      ndk {
        abiFilters(*requestedArchitectures.split(','))
      }
    }

    externalNativeBuild {
      cmake {
        cppFlags '-std=c++17 -Wall -Wextra -Werror'
      }
    }
  }

  externalNativeBuild {
    cmake {
      path 'src/main/cpp/CMakeLists.txt'
      version '3.22.1'
    }
  }
}

dependencies {
  implementation project(':expo-modules-core')
  testImplementation 'junit:junit:4.13.2'
  testImplementation 'org.robolectric:robolectric:4.16.1'
}

tasks.withType(Test).configureEach {
  javaLauncher = javaToolchains.launcherFor {
    languageVersion = JavaLanguageVersion.of(21)
  }
}